New feature: a GUI proxy for BaCon

[vovchik]

Dear Joe,

Thanks. I have attached a real toggle button demo based on yours. The advantage of using a real one in the Play/Pause case is that, when playing, it stays "prelit" or highlighted. Otherwise it is much the same. And using a toggle button will save space in the compact gui.

Here is the code:

OPTION GUI TRUE
PRAGMA GUI gtk2
OPTION PARSE FALSE

' Needed if we run this GTK2 sample in GTK3
PRAGMA OPTIONS -Wno-deprecated-declarations
PRAGMA OPTIONS -Wno-write-strings -Wno-deprecated

DECLARE (*ATTACH)() = gtk_fixed_put TYPE void

' ------------------
SUB SPIN_TOGGLE()
' ------------------
IF  cnt  THEN
CALL GUISET(id, "spinner", "active", 0)
CALL GUISET(id, "toggle", "label", "▶")
CALL GUISET(id, "toggle", "active", FALSE)
CALL GUISET(id, "toggle", "tooltip-text", "Paused.")
PRINT "Spinner OFF."
cnt = 0
ELSE
' stays prelit - highlighted if on
CALL GUISET(id, "spinner", "active", 1)
CALL GUISET(id, "toggle", "label", "⏸")
CALL GUISET(id, "toggle", "active", TRUE)
CALL GUISET(id, "toggle", "tooltip-text", "Playing.")
PRINT "Spinner ON."
cnt = 1
END IF
END SUB

' ------------------
SUB MY_QUIT()
' ------------------
' quit program
PRINT NL$, "End of demo...", NL$
END
END SUB


' ------------------
SUB MK_GUI()
' ------------------
' set window size
win_w = 220
win_h = 60

' define all gui elements
id = GUIDEFINE(" \
{ type=WINDOW name=window callback=delete-event } \
{ type=FIXED name=fixed parent=window } \
{ type=SPINNER name=spinner } \
{ type=TOGGLE_BUTTON name=toggle callback=toggled } \
{ type=IMAGE name=image } \
{ type=BUTTON name=myexit  callback=clicked }")

' widget properties

' window
CALL GUISET(id, "window", "window-position", GTK_WIN_POS_CENTER)
CALL GUISET(id, "window", "width-request", win_w)
CALL GUISET(id, "window", "height-request", win_h)
CALL GUISET(id, "window", "title", "Spinner")

' buttons
CALL GUISET(id, "toggle", "width-request", 35)
CALL GUISET(id, "myexit", "width-request", 70)

CALL GUISET(id, "toggle", "height-request", 35)
CALL GUISET(id, "myexit", "height-request", 35)

CALL GUISET(id, "toggle", "label", "▶")
CALL GUISET(id, "myexit", "label", "Exit")

' define tooltips
CALL GUISET(id, "toggle", "tooltip-text", "Toggle BaCon throbber demo.")
CALL GUISET(id, "myexit", "tooltip-text", "Quit BaCon throbber demo.")

' spinner size
CALL GUISET(id, "spinner", "width-request", 24)
CALL GUISET(id, "spinner", "height-request", 24)

' widget placement
CALL GUIFN(id, "fixed", ATTACH, GUIWIDGET(id, "toggle"), 10, 10)
CALL GUIFN(id, "fixed", ATTACH, GUIWIDGET(id, "spinner"), 80, 18)
CALL GUIFN(id, "fixed", ATTACH, GUIWIDGET(id, "myexit"),  140, 10)
END SUB

' make gui
MK_GUI()

' endless loop
WHILE TRUE
event$ = GUIEVENT$(id)
PRINT "Event: ", event$
SELECT event$
CASE "window"
END
CASE "toggle"
SPIN_TOGGLE
CASE "myexit"
MY_QUIT
END SELECT
SLEEP 1
WEND

Hope it works for you.

With kind regards,
vovchik

[bigbass]

Hello vovchik

I like It!
it does what you need and looks good

we don't need a " gtk toggle widget or switch "
the idea is it can be simulated with any type
of button when needed

Joe

[rikky]

I can see that your stop button is UTF8$(2908)
Somehow my system does not have utf8 2908
Nor does it have a utf8 2909, which is supposedly the pause button in the vovchick radio gui.

I have a nice square on 9724 : ◼
And could not find a proper pause button.

The best pause I have is utf8 1520 : װ
But that one is not fat enough.

☺ Rik.

Attachments:

[vovchik]

Dear Rik,

Thanks for testing and pointing out the absence of those characters in some fonts. I am using Fira Sans Medium on Pi and Mint as my defaults:

Fira Fonts

which are available on Github and from Mozilla (the developers). It is slightly more condensed than the usual Sans Serif and looks better on my devices. It also has the characters in question.

I'll have to check for the existence special UTF8 chars in future...

With kind regards,
vovchik

[vovchik]

Dear all,

Another benefit of using a real toggle button ({ type=TOGGLE_BUTTON name=toggle callback=toggled }) for play/pause in the GUI defintion is that the space bar can also control action: space bar off and space bar on without any additional code. Just discovered that. UPDATE: And Joe's button also works the same way, so the space bar will start and stop both. Also a nice discovery.

With kind regards,
vovchik

[vovchik]

Dear all,

Here is a throbber again, but I added a utility function that can be used in all our GUI proxy gtk code (gtk2/3). It returns the size of a label (even with pango markup) and takes into account rotation, if any. Run in a terminal to see the output. I have also included a move routine for items in a fixed box.

With kind regards,
vovchik

Attachments:

vov-real-toggle-gtk-src.tar.gz (3.57 KB)

[Pjot]

Thanks vovchik,

Nice discoveries which come handy

BR
Peter

[vovchik]

Dear all,

Here is an animated rotating label (gtk2/3). Hope it works for you.

With kind regards,
vovchik

Attachments:

bacon-rotating-label.tar.gz (3.71 KB)

[Pjot]

Hi vovchik,

All work, nice to see the code being so small and concise!

Thanks,
Peter

[vovchik]

Dear all,

Here is another little HUG demo from the past ported to the GTK proxy GUI. It works for me (gtk2/3) and hope it works for you, too.

With kind regards,
vovchik

Attachments:

bmw-scroll-gtk.tar.gz (3.84 KB)

[Pjot]

Thanks vovchik,

All works on my system. What I like about your code (again!) is the small amount of commands needed to create the GUI.

The small code footprint was one of the design goals of the new GUI commands, and it seems to fulfill its promise

Best regards
Peter

[bigbass]

working nicely on the rpi3!

Joe

[Pjot]

All,

You probably may have noticed some updates on fossil related to a new widget backend. The GUI functions now also support the Curses Development Kit (CDK) from Thomas Dickey. This is a widget library for the ASCII console.

This library should be available in your favorite repo (RPM based or DEB based).

The current status is still somewhat experimental, but it already is fairly usable. The biggest problem is the lack of property naming. On the positive side however, the API has a very consistent naming convention and allows async updates as well.

So it was relatively easy to implement code generation for all widgets. With just a small addition, where we have to use a comma separated list for the properties, the CDK backend now can be used in our code.

Attached 2 screenshots, and below the code of my test program. The other program, of which I created HUG and Motif versions before, can be found here.

Regards
Peter

OPTION GUI TRUE
PRAGMA GUI cdk

DECLARE item[] = { "one", "two", "three", "four" } TYPE const char const*

DECLARE menus[MAX_MENU_ITEMS][MAX_SUB_ITEMS] TYPE const char const*

menus[0][0] = "</B>File"
menus[0][1] = "</B/5>Open    "
menus[0][2] = "</B/5>Save    "
menus[0][3] = "</B/5>Save As "
menus[0][4] = "</B/5>Quit    "
menus[1][0] = "</B>Edit"
menus[1][1] = "Copy   "
menus[1][2] = "Cut    "
menus[1][3] = "Paste  "

DECLARE submenu[] = { 5, 4 } TYPE int

DECLARE sloc[] = { LEFT, LEFT } TYPE int

id = GUIDEFINE(" \
   { type=window name=screen } \
   { type=menu name=menu args=screen,menus,2,submenu,sloc,TOP,A_BOLD|A_UNDERLINE,A_REVERSE } \
   { type=mentry name=mentry args=screen,4,4,\"Text:\",\"\",A_BOLD,32,vMIXED,50,10,2,0,1,1 callback=KEY_ESC,esc } \
   { type=calendar name=calendar args=screen,61,5,\"Calendar\",12,6,2020,A_BOLD,A_BOLD,A_BOLD,A_BOLD,1,1 callback=KEY_ENTER callback=KEY_ESC,esc } \
   { type=button name=button args=screen,4,18,\"This is NOK\",NULL,1,1 callback=KEY_ENTER callback=KEY_ESC,esc } \
   { type=button name=exit args=screen,23,18,\"  EXIT  \",NULL,1,1 callback=KEY_ENTER callback=KEY_ESC,esc } \
   { type=entry name=entry args=screen,13,23,\"Information:\",\"\",A_BOLD,95,vMIXED,20,0,20,1,1 callback=KEY_ENTER callback=KEY_ESC,esc } \
   { type=scroll name=scroll args=screen,43,18,RIGHT,10,20,\"\",item,4,TRUE,A_BOLD,1,1 callback=KEY_ESC,esc }")

CALL GUISET(id, "button", Button, " BLUE ", TRUE)
CALL GUISET(id, "button", ObjectBackgroundColor, "</40>")
CALL GUISET(id, "mentry", MentryValue, "Press <ESC> to get into the menu and press <TAB> to switch widget")

WHILE TRUE
   event$ = GUIEVENT$(id)

   SELECT event$
       CASE "esc"
           action = activateCDKMenu(GUIWIDGET(id, "menu"), 0)
           IF action = 3 THEN END
       CASE "exit"
           END
   ENDSELECT
WEND


Attachments:

[vovchik]

Dear Peter,

Thanks. Always nice to have maximum flexibility in GUI creation.

I have installed cdk and cdk-dev packages on Mint and Pi. I get the following error:

Converting 'peter-cdkdemo1.bac'... done, 51 lines were processed in 0.018 seconds.
Compiling 'peter-cdkdemo1.bac'... cc -fno-pie -Wno-implicit -Os -fdata-sections -ffunction-sections -Wl,--gc-sections -c peter-cdkdemo1.bac.c
Makefile.bacon:6: recipe for target 'peter-cdkdemo1.bac.o' failed

peter-cdkdemo1.bac:2:10: fatal error: cdk.h: No such file or directory

And cdk.h exists on both machines (/usr/include/cdk/cdk.h). I have run sudo ldconfig.

Any advice?

With kind regards,
vovchik

[Pjot]

Hi vovchik,

The implementation assumes the 'cdk.h' header file is in '/usr/include'. But on your RPI it seems to reside in '/usr/include/cdk'.

In that case, can you add the following line to the top of the program:

PRAGMA OPTIONS -I/usr/include/cdk


This should solve the error you're facing.

BR
Peter